// Этот скетч использует зуммер для воспроизведения мелодий.
// Команда Arduino tone() будет издавать звуки определенной частоты.
// Мы создаем функцию, которая сопоставляет символ нотной гаммы
// ("До-ре-ми-фа...До") соответствующей частоте из следующей таблицы:
// note 	frequency
// c     262 Hz
// d     294 Hz
// e     330 Hz
// f     349 Hz
// g     392 Hz
// a     440 Hz
// b     494 Hz
// C     523 Hz
const int buzzerPin = 9;
// Мы создали массив с нотами, которые хотим воспроизвести, измените эти значения, чтобы создать свои мелодии!
// Длина должна равняться общему количеству нот и пауз
const int songLength = 18;
// Обозначение нот представляет собой массив из текстовых символов,
// соответствующим нотам в песне. Пробел означает паузу (пустую ноту)
char notes[] = "cdfda ag cdfdg gf "; // пробелы означают паузы
// Ритм задается массивом из длительности нот и пауз между ними.
// "1" - четвертная нота, "2" - половинная, и т.д.
// Не забывайте, что пробелы должны быть тоже определенной длинны.
int beats[] = {1,1,1,1,1,1,4,4,2,1,1,1,1,1,1,4,4,2};
// "tempo" это скорость проигрывания мелодии.
// Для того, чтобы мелодия проигрывалась быстрее, вы
// должны уменьшить следующее значение.
int tempo = 150;
void setup() 
{
  pinMode(buzzerPin, OUTPUT);
}
void loop() 
{
  int i, duration;
  for (i = 0; i < songLength; i++) // пошаговое воспроизведение из массива
  {
    duration = beats[i] * tempo;  // длительность нот/пауз в ms    
    if (notes[i] == ' ')          // если нота отсутствует? 
    {
      delay(duration);            // тогда не большая пауза
    }
    else                          // в противном случае играть
    {
      tone(buzzerPin, frequency(notes[i]), duration);
      delay(duration);            // ждать пока проигрывается
    }
    delay(tempo/10);              // маленькая пауза между нотами
  }
  // Мы хотим, чтобы мелодия проиграла всего один раз, так что здесь остановимся окончательно:
  while(true){}
  // Если же вы хотите, чтобы мелодия играть снова и снова, Удалить вышеуказанное заявление
}
int frequency(char note) 
{
  // Эта функция принимает символ ноты (a-g), и возвращает
  // частоту в Гц для функции tone().
  int i;
  const int numNotes = 8;  // количество хранимых нот
  char names[] = { 'c', 'd', 'e', 'f', 'g', 'a', 'b', 'C' };
  int frequencies[] = {262, 294, 330, 349, 392, 440, 494, 523};
  // Теперь мы будем искать во всем массиве, символ ноты и если находим, возвращаем частоту для этой ноты.  
  for (i = 0; i < numNotes; i++)  // пошаговый перебор нот
  {
    if (names[i] == note)         // если находим
    {
      return(frequencies[i]);     // возвращаем частоту
    }
  }
  return(0);  // Поиск символа не дал результата? Но, необходимо  вернуть какое-то значение, так вернем 0.
}

Ülesanne 6 Muusikaline vinguja:

https://www.tinkercad.com/things/hsYnDWZH8Sj?sharecode=1uUgAqkAgCVYl5NHyunvWwIeK0U952hkjNUMUkUZugU

Ma kasutasin selle projekti jaoks:

• 1 Buzzer
• 1 Arendusplaat
• 7 Juhtmed
• 1 Arduino Uno
• 1 Potentsiomeeter

Kõik režiimid:

Ma kasutasin 3 režiimid, 1 režiim kasutab noted c,e,g,C; 2 režiim kasutab noted a,g,f,e,d,c; 3 režiim kasutab noted e,f,g,a,b,C

Kood:

const int BUZZERPIN = 9;
const int POTENPIN = A0;
const int melodyCount = 3;
const int melodyThresholds[melodyCount] = {341, 682, 1023};
const int melody1[] = {261, 329, 392, 523};
const int noteDurations1[] = {4, 4, 4, 4};
const int melody2[] = {440, 392, 349, 330, 294, 261};
const int noteDurations2[] = {8, 8, 8, 8, 8, 8};
const int melody3[] = {329, 349, 392, 440, 494, 523};
const int noteDurations3[] = {2, 2, 2, 2, 2, 2};
void setup() 
{
  pinMode(BUZZERPIN, OUTPUT);
}
void loop() 
{
  
  int potValue = analogRead(POTENPIN);
  
  int selectedMelody = 0;
  for (int i = 0; i < melodyCount; i++) {
    if (potValue < melodyThresholds[i]) {
      selectedMelody = i;
      break;
    }
  }
  
  playMelody(selectedMelody);
  delay(100); 
}
void playMelody(int melodyIndex) 
{
  const int* melody;
  const int* noteDurations;
  int noteCount;
 
  switch (melodyIndex) {
    case 0:
      melody = melody1;
      noteDurations = noteDurations1;
      noteCount = sizeof(melody1) / sizeof(int);
      break;
    case 1:
      melody = melody2;
      noteDurations = noteDurations2;
      noteCount = sizeof(melody2) / sizeof(int);
      break;
    case 2:
      melody = melody3;
      noteDurations = noteDurations3;
      noteCount = sizeof(melody3) / sizeof(int);
      break;
    default:
      return;
  }
  
  for (int i = 0; i < noteCount; i++) {
    int noteFrequency = melody[i];
    int noteDuration = 1000 / noteDurations[i];
    tone(BUZZERPIN, noteFrequency, noteDuration);
    delay(noteDuration * 1.3); 
    noTone(BUZZERPIN);
    delay(50); 
  }
}

Buzzeri kasutamine:

• mänguasjades
• kodumasinate puhul
• telefoni teel
• signalisatsiooniseadmetes
• erinevates sireenides